DECLARE
    v_tablename  VARCHAR2(100);
    v_sql        VARCHAR2(1000);
    v_empno      emp.empno%TYPE;
    emp_row      emp%ROWTYPE;
    TYPE ref_cur IS REF CURSOR;
    cur1         ref_cur;
BEGIN
    v_tablename := 'emp';
    v_sql := 'SELECT * FROM ' || v_tablename || ' WHERE empno = :v_empno';
    v_empno := 7788;
    OPEN cur1 FOR v_sql USING v_empno;
    LOOP
        FETCH cur1 INTO emp_row;
        EXIT WHEN cur1%NOTFOUND;
        dbms_output.put_line(emp_row.ename);
    END LOOP;
    CLOSE cur1;
END;
/

 마농님 감사합니다. 점심은 잘 드셨는지요?

한가지 질문을 더 드리자면 

V_SQL 이 특정 테이블 ROW를 반환하는게 아니라 두 개이상의 테이블 조인으로 인해 생기는

복합 컬럼이 OUTPUT 일 경우에는 EMP_ROW를 어떻게 선언해야 되나요?

DECLARE
    v_tablename  VARCHAR2(100);
    v_sql        VARCHAR2(1000);
    v_empno      emp.empno%TYPE;
    TYPE result_type IS RECORD( empno NUMBER
                              , ename VARCHAR2(30)
                              , dname VARCHAR2(30)
                              );
    result_set   result_type;
    TYPE ref_cur IS REF CURSOR;
    cur1         ref_cur;
BEGIN
    v_tablename := 'emp';
    v_sql := 'SELECT e.empno, e.ename, d.dname';
    v_sql := v_sql || ' FROM ' || v_tablename || ' e, dept d';
    v_sql := v_sql || ' WHERE e.deptno = d.deptno AND e.empno = :v_empno';
    v_empno := 7788;
    OPEN cur1 FOR v_sql USING v_empno;
    LOOP
        FETCH cur1 INTO result_set;
        EXIT WHEN cur1%NOTFOUND;
        dbms_output.put_line(result_set.ename || '-' || result_set.dname);
    END LOOP;
    CLOSE cur1;
END;
/