위와 같은 Trigger를 만들었을 때 가장 문제가 되는 것은 
두개이상의 데이터를 업데이트 했을 때, @napn, @qty, @code의 데이터는 무엇으로 지정이 될까요? 

Trigger는 논리적 오류를 내포하고 있는 것 같습니다. 

Create Trigger tgUpdateTrigger
on Test
For Update
As
Begin
set nocount on

update a
 set a.count = a.count + b.count
from test A
 inner join inserted B
 ON A.[NA-P/N] = B.[NA-P/N]
 where b.code = '0'

set nocount off
End

제가 질문을 잘못 한것 같습니다.

실제 트리거는 아래와 같이 작성 되어 있는데 .님이 지적하신데로 복수건을 갱신할때 문제가 생기네요
어떻게 수정하면 좋을지 조언좀 부탁하겠습니다.

아래는 실제 작성한 트리거 입니다.

IF EXISTS (SELECT name FROM sysobjects
WHERE name = 'tgUpdateTrigger' AND type = 'TR')
DROP TRIGGER tgUpdateTrigger
GO

CREATE TRIGGER tgUpdateTrigger
ON [部品納入残]
FOR  Update
AS
declare @UpdateCnt int,
        @KaisyaSyubetu varchar(3),
        @ZigyousyoSyubetu varchar(3),
        @NAPN varchar(16),
        @Qty decimal(9,2),
        @Zyoutai tinyint
      SELECT
        @KaisyaSyubetu = upt.[会社種別],
        @ZigyousyoSyubetu = upt.[事業所種別],
        @NAPN = upt.[NA-P/N],
        @Qty  = upt.[数量],
        @Zyoutai  = upt.[状態]
      FROM inserted upt

IF UPDATE ([状態])
   if @Zyoutai  = '0'
      begin
        update [部品納入残（合計)]
          set [残数量] = [残数量] + @Qty,
              [更新年月日] = getdate()
        where [会社種別]   = @KaisyaSyubetu
          and [事業所種別] = @ZigyousyoSyubetu
          and [NA-P/N]     = @NAPN
      end
   if @Zyoutai  = '1'
     begin
         update [部品納入残（合計)]
          set [残数量] = [残数量] - @Qty,
              [更新年月日] = getdate()
        where [会社種別]   = @KaisyaSyubetu
          and [事業所種別] = @ZigyousyoSyubetu
          and [NA-P/N]     = @NAPN
      end
GO

역시 복수개 이상일때는 처음 예문과 같은 오류를 내포하고 있습니다. 

검증을 한 다음 사용하시기 바랍니다.


CREATE TRIGGER TGUPDATETRIGGER
ON [部品納入残]
FOR UPDATE
AS
BEGIN
SET NOCOUNT ON
update A
 Set a.[残数量] = a.[残数量] + case when b.[状態] = '0' then  b.[残数量]
            when b.[状態] = '1' then  -1 * b.[残数量] end
  , a.[更新年月日] = getdate()
from [部品納入残（合計)] A
inner join Inserted B
on a.[会社種別]  = b.[会社種別]
and a.[事業所種別] = b.[事業所種別]
and a.[NA-P/N] = b.[NA-P/N]
SET NOCOUNT OFF
END

안된다면 msn이나 nate의 주소를 주십시오. ^^