' 대신에 '' 을 넣으면 됩니다.

쌍따옴표가 아닌 ' 를 두번 쓰셔야합니다.

(''A'',''가''), (''B'',''나'')

 아니면

EXCUTE IMMEDIATE 'SELECT :1, :2 FROM DUAL' USING '가','나';

이렇게 하셔도 됩니다.

저같은 경우에는 위의 것은 상수일때 변수일때는 아래것을 주로 사용하고 있습니다.

정명곤님 감사합니다.. ^^

근데.... 제가 질문을 좀 잘못 올렸네요.... ㅠㅠ

제가 원했던건 

V_DYNAMIC_CONDITION := ('A', '가'), ('B', '나'), .............................................. ;

이렇게 해서 V_DYNAMIC_CONDITION을 동적으로 만들어서 위의 /*DYNAMIC*/ 부분에 넣으려고 했던거거든요....

근데 위에 변수 바인딩 하는곳에서 SINGLE QUOTATION이 있어서 문제가 되고 있습니다....

다시 한번 도움 부탁드립니다..... (__)

대충 만들어서 여러가지가 고려가 안되어 있습니다.

IN의 값이 여러개라면 아래처럼 실행하면 에러 납니다. 

여러행 인출한다고 에러납니다.

CREATE OR REPLACE PROCEDURE ABC IS

 V_SQL VARCHAR2(1000);

 V_DY  VARCHAR2(1000);

 V_VAL VARCHAR2(1000);

 V_VAL2 VARCHAR2(1000);

BEGIN

    V_DY := ' (''가'',''가''),(''나'',''나'')';

   V_SQL := 'SELECT VAL, VAL2 FROM AX 

                   WHERE (VAL, VAL2) IN (' || V_DY || ')';

   EXECUTE IMMEDIATE V_SQL INTO V_VAL, V_VAL2;

   DBMS_OUTPUT.PUT_LINE ( V_VAL || V_VAL2);

   EXCEPTION

     WHEN NO_DATA_FOUND THEN

       NULL;

     WHEN OTHERS THEN

       -- Consider logging the error and then re-raise

       RAISE;

END ABC;

/

 그런데 근본적으로

여러행을 인출하는 SELECT는 EXECUTE IMMEDIATE로 처리가 안될텐데요

그 부분은 알아서 하시리라 믿고 ^_^;

CREATE OR REPLACE PROCEDURE abc
IS
  v_sql  VARCHAR2(1000);
  v_dy   VARCHAR2(1000);
  v_val  VARCHAR2(1000);
  v_val2 VARCHAR2(1000);
  TYPE ref_cursor_type IS REF CURSOR;
  rc   ref_cursor_type;
BEGIN
  v_dy  := '(''가'',''가''),(''나'',''나'')';
  v_sql := 'SELECT val, val2
              FROM ax
             WHERE (val, val2) IN (' || v_dy || ')';
  --DBMS_OUTPUT.PUT_LINE(v_sql);
  OPEN rc FOR v_sql;
  LOOP
    FETCH rc INTO v_val, v_val2;
    EXIT WHEN rc%NOTFOUND;
    DBMS_OUTPUT.PUT_LINE(v_val || '/' || v_val2);
  END LOOP;
EXCEPTION
  WHEN NO_DATA_FOUND THEN
    NULL;
  WHEN OTHERS THEN
    -- Consider logging the error and then re-raise
    RAISE;
END;
/

정명곤님, 마농님....

친절하고 정확한 답변 감사합니다. ^^